Bomberman - создаём бомбу

После примерного наброска основных принципов игры в незамудрённом виде можно заняться более подробной проработкой деталей.

Я решил заняться наиболее интересным и тем, что в моём первом варианте было реализовано слабовато - это бомба.

Далее идёт описание принятых решений по задумкам из первого отчёта и относительно подробный экскурс по проектированию и реализации бомбы.

Начну с того, что я солидарен с Altmer'ом, что "бомбермен это не тетрис и не змейка, эта игра имеет все признаки 'большой' игры" и поэтому я не поленился разработать мини отчёт характеризующий разработку данной игры:

• Реализация. Для данной программы я выбрал итеративный подход реализации. Хотя основные требования выработал вначале и опубилковал их в первом отчёте.
• Жизненный цикл разработки данного проекта получается более как эволюционный нежели прототипированный. Хотя элементы прототипирования присутствуют. Например набросок из первого отчёта можно смело считать подобием прототипа. Хотя при подавляющем эволюционировании я многое уже изменил в структуре и принципах взаимодействия классов.
• Планирование проекта получается по большей части формальное заблаговременное, но так же  имеются элементы инкрементации. Т.к. я могу последовательно размышлять над добавлением или уменьшением тех или иных деталей конкретных элементов.
• Проектирование я комбинирую с написанием кода.

Теперь нужно сказать о моих окончательных решениях в реализации некоторых деталей, вопросами о которых я задавался в первом отчёте.

• Я изменил взгляды на цифровое представление поля, но это я поясню в следующей теме о проектировании поля боя, тем более что я это ещё не реализовал окончательно.
• Определился с динамикой бомбы, что и буду описывать чуть ниже.
• Модель главного героя будет 3-х мерной и в её реализации мне поможет Almost, который в отличии меня умеет моделить). Насчёт крипов пока неизвестно.

На этом с определёнными деталями пока что всё.

И так, приступим к проектированию и написанию объекта-бомбы.
Начинаю с того, что открываю заготовку приложения для разработки какой-либо 3D штучек(в этот каркас приложения у меня входит создание базы 3D пространства, камер и обработка основных контролов).

Создаю основной класс бомбы - наследника от TGLDummyCube и начинаю размышлять...
Необходимо, чтобы отображался спрайт бомбы, который будет пульсировать пока она не взорвётся по таймеру или по приказу. Таким образом создаём объекты и методы в нашем классе для этих пунктов "правильной" бомбы)

После прототипирования данных элементов класс бомбы начинает выглядить так:

Класс бомбы

unit uBomb;

interface

uses
  ...стандартные модули..., ...модули сцены..., ...свои модули...;

type
  TBomb = class(TGLDummyCube)
  private
    fBombSprite : TGLPlane;
    fRadius : smallint;
    fPulsFactor : single;
    fTimer : single;
    fExploded : boolean; // взорвалась ли
    procedure MainInit;
  public
    procedure DoProgress(const progressTime: TProgressTimes); override;
  public
    constructor CreateAsChild(aParentOwner: TGLBaseSceneObject; aRadius: smallint);
    destructor Destroy; override;
    property Radius: smallint read fRadius;
    property Exploded: boolean read fExploded;
  end;

Т.е. спрайт бомбы будет отображаться на TGLPlain'е, который будет крутиться фронтом всегда к камере(биллборд), как спрайты у систем частиц.

Теперь можно написать следующие обработчики: это создание основных элементов и биллбординг бомбы.

И вот что получилается:

Раздел реализации модуля бомбы

implementation

const
  c_MIN_SIZE = 0.7;
  c_MAX_SIZE = 1;
  c_PULS_FACTOR = 1;

{ TBomb }

constructor TBomb.CreateAsChild(aParentOwner: TGLBaseSceneObject; aRadius: smallint);
begin
  inherited CreateAsChild(aParentOwner);
  fRadius := aRadius;
  MainInit;
end;

destructor TBomb.Destroy;
begin
  FreeAndNil(fBombSprite);
  inherited Destroy;
end;

procedure TBomb.MainInit;
begin
  fBombSprite := TGLPlane.CreateAsChild(Self);
  with fBombSprite do
  begin
    Width := c_MIN_SIZE;
    Height := c_MIN_SIZE;
    Material.MaterialLibrary := BSF.MatLib;
    Material.LibMaterialName := 'bomba';
  end;
  fPulsFactor := c_PULS_FACTOR;
  fTimer := 3;
  fExploded := False;
end;

procedure TBomb.DoExplosion;
begin
  fBombSprite.Visible := False;
  fExploded := True;
end;

procedure TBomb.DoProgress(const progressTime: TProgressTimes);
var
  DTime : single;
  cam_ap : TVector;
begin
  DTime := progressTime.deltaTime;
  if not(fExploded) then
  begin
    // пульсация
    fBombSprite.Width := fBombSprite.Width + DTime * fPulsFactor;
    if fBombSprite.Width > c_MAX_SIZE then fBombSprite.Width := c_MAX_SIZE;
    if fBombSprite.Width < c_MIN_SIZE then fBombSprite.Width := c_MIN_SIZE;
    fBombSprite.Height := fBombSprite.Width;
    if fBombSprite.Width >= c_MAX_SIZE then fPulsFactor := -c_PULS_FACTOR;
    if fBombSprite.Width <= c_MIN_SIZE then fPulsFactor := c_PULS_FACTOR;
    // делаем билборд
    fBombSprite.Up.SetVector(VectorMake(0, 1, 0));
    cam_ap := Self.Scene.CurrentGLCamera.AbsolutePosition;
    fBombSprite.Direction.SetVector(VectorSubtract(cam_ap, fBombSprite.AbsolutePosition));
    // timer
    fTimer := fTimer - DTime;
    if fTimer <= 0 then
      DoExplosion;
  end;
  // обработка взрыва

end;

end.

Запускаем, проверяем - нормалёк)

Сразу хотел бы заметить, что моя версия билборда бомбы не очень корректно смотрится при наличии нескольких бомб на поле - когда камера передвигается бомбы начинают крутиться чтобы всегда смотреть на неё)
Если кто подскажет мне как правильнее сделать билборд, то я буду ток рад)

Теперь можно подумать и о взрыве.

В плане взрыва я решил немножко отойти от привычного типа взрыва классического бомбера и сделал, на мой взгляд, чутка поинтереснее.

Я сделал осколочный взрыв. Т.е. добавил в класс бомбы 4 экземпляра класса осколка, создал некий контроллер системы частиц для эффекта огненного шлейфа, прицепил к осколкам и запустил это дело посмотреть, получилось весьма красиво)

В результате класс бомбы стал выглядеть так:

unit uBomb;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls,
  GLScene, GLWin32Viewer, GLCrossPlatform, BaseClasses, GLPolyhedron,
  GLMaterial, GLCoordinates, GLObjects, GLCadencer, GLContext,
  GLRenderContextInfo, GLBitmapFont, GLWindowsFont, GLHUDObjects,
  VectorGeometry, VectorTypes, GLKeyboard,
  uBombFragment, uBaseGLSceneFrame, uSimpleUtils;

type
  TFragName = (fnNorth, fnSouth, fnEast, fnWest);

  TBomb = class(TGLDummyCube)
  private
    fBombSprite : TGLPlane;
    fNorthFragment : TBombFragment;
    fSouthFragment : TBombFragment;
    fEastFragment : TBombFragment;
    fWestFragment : TBombFragment;
    fRadius : smallint;
    fPulsFactor : single;
    fTimer : single;
    fExploded : boolean; // взорвалась ли
    fDestroyed : boolean; // уничтожена ли полностью(осколки тоже)
    procedure MainInit;
  public
    function IsFragActual(aFN: TFragName): boolean;
    function GetFragPos(aFN: TFragName): TPointFloat;
    procedure FragDoExplosion(aFN: TFragName);
    procedure DoExplosion;
    procedure DoProgress(const progressTime: TProgressTimes); override;
  public
    constructor CreateAsChild(aParentOwner: TGLBaseSceneObject; aRadius: smallint);
    destructor Destroy; override;
    property Radius: smallint read fRadius;
    property Exploded: boolean read fExploded;
    property Destroyed: boolean read fDestroyed;
  end;

И скрин этого дела:

Но о подробностях я пожалуй умолчу, чтобы всётаки сохранять некоторую интригу)

Ну вот. Вроде больше про бомбу говорить нечего) Ведь требований для её реализации оказалось совсем не много.
Но если я чего забыл, то вопросы всегда можно задать в комментах.